# WinPR: Windows Portable Runtime
# libwinpr-crt cmake build script
#
# Copyright 2012 Marc-Andre Moreau <marcandre.moreau@gmail.com>
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

set(CRT_FILES
    alignment.c
    conversion.c
    buffer.c
    memory.c
    unicode.c
    string.c
    assert.c
)

if(CMAKE_VERSION VERSION_LESS "3.19")
  include(CheckSymbolExists)
  check_symbol_exists(regcomp regex.h WINPR_HAVE_REGCOMP)
  check_symbol_exists(regexec regex.h WINPR_HAVE_REGEXEC)
  check_symbol_exists(regfree regex.h WINPR_HAVE_REGFREE)
  if(WINPR_HAVE_REGCOMP AND WINPR_HAVE_REGEXEC AND WINPR_HAVE_REGFREE)
    set(WINPR_HAVE_REGCOMP ON)
  else()
    set(WINPR_HAVE_REGCOMP OFF)
  endif()

else()

  include(CheckSourceCompiles)
  if(APPLE)
    set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror=unguarded-availability-new")
  endif()
  check_source_compiles(
    C
    [[
    #include <regex.h>

    int main(void) {
        regex_t preg = {0};
        char regex[] = "foobar";
        regcomp(&preg, regex, 0);
        regexec(&preg, regex, 0, 0, 0);
        regfree(&preg);
        return 0;
    }
    ]]
    WINPR_HAVE_REGCOMP
  )
endif()

if(WINPR_HAVE_REGCOMP)
  winpr_definition_add(WINPR_HAVE_REGCOMP)
endif()

if(WITH_UNICODE_BUILTIN)
  list(APPEND CRT_FILES unicode_builtin.c)
else()
  if(ANDROID)
    list(APPEND CRT_FILES unicode_android.c)
  elseif(NOT APPLE AND NOT WIN32)
    find_package(ICU REQUIRED i18n uc io data)
    winpr_pc_add_requires_private("icu-uc")
    winpr_pc_add_requires_private("icu-io")
    winpr_pc_add_requires_private("icu-i18n")
    list(APPEND CRT_FILES unicode_icu.c)
    winpr_system_include_directory_add(${ICU_INCLUDE_DIRS})
    winpr_library_add_private(${ICU_LIBRARIES})
  elseif(APPLE)
    list(APPEND CRT_FILES unicode_apple.m)
    find_library(FOUNDATION_FRAMEWORK Foundation REQUIRED)
    winpr_library_add_private(${FOUNDATION_FRAMEWORK})
  endif()
endif()

winpr_module_add(${CRT_FILES})

if(BUILD_TESTING_INTERNAL OR BUILD_TESTING)
  add_subdirectory(test)
endif()
